Skip to content

← Späť

DU3

Pomoc k úlohám 3.1 a 3.2 – record syntax a Maybe

Riešenia sú v help.hs. Spustíš ich cez runghc help.hs alebo v GHCi (ghci help.hs). Najprv si skús úlohy vyriešiť sám a až potom si porovnaj kód.


  1. Čo potrebuješ vedieť o record syntax
  2. Úloha 3.1
  3. availableTitles
  4. borrowedBy
  5. borrowBook
  6. returnBook
  7. Úloha 3.2 – borrowBook s Maybe
  8. Časté chyby

1. Čo potrebuješ vedieť o record syntax

data Book = Book
  { title      :: String
  , author     :: String
  , loanStatus :: LoanStatus
  } deriving (Eq, Show)

Z tejto definície vzniknú tri veci:

1. Funkcie na čítanie polí. Haskell sám vytvorí title, author a loanStatus:

title      :: Book -> String
loanStatus :: Book -> LoanStatus

title book1       -- "Duna"
loanStatus book2  -- Borrowed "Jana"

Sú to obyčajné funkcie, takže ich môžeš dať do map alebo filter: map title books.

2. Úprava poľa. Zápis book { loanStatus = Available } vytvorí novú knihu, ktorá má zmenené len pole loanStatus. Ostatné polia sa skopírujú. Pôvodná kniha sa nezmení, v Haskelli sa nič neprepisuje.

3. Porovnávanie cez ==. Vďaka deriving Eq pri LoanStatus môžeš písať loanStatus b == Available alebo loanStatus b == Borrowed "Jana".


2. Úloha 3.1

availableTitles – názvy dostupných kníh

availableTitles :: [Book] -> [String]
availableTitles books = map title (filter isAvailable books)
  where
    isAvailable b = loanStatus b == Available

Rovnaký vzor ako squaresOfEvens (najprv filter, potom map):

  1. filter isAvailable books ponechá len knihy so stavom Available
  2. map title z každej knihy vytiahne názov

Výsledok je [String], nie [Book], preto je na konci map title.

availableTitles library  -- ["Duna"]

borrowedBy – knihy vypožičané osobou

borrowedBy :: String -> [Book] -> [Book]
borrowedBy person books = filter byPerson books
  where
    byPerson b = loanStatus b == Borrowed person

Tu sa vracajú celé knihy, takže stačí filter, bez map.

Borrowed person je hodnota typu LoanStatus, rovnako ako Available. Borrowed "Jana" sa rovná len Borrowed "Jana", nie Borrowed "Peter", takže == porovná aj meno.

byPerson vidí person z hlavnej funkcie, lebo je vo where (rovnako ako isLong videl n pri countLong).

map title (borrowedBy "Jana" library)  -- ["1984","Solaris"]

borrowBook – vypožičanie knihy

borrowBook :: String -> Book -> Book
borrowBook person book
  | loanStatus book == Available = book { loanStatus = Borrowed person }
  | otherwise                    = book
  • kniha je voľná: vrátim novú knihu so stavom Borrowed person
  • kniha už je požičaná: vrátim ju bez zmeny (book)
borrowBook "Peter" book1
-- Book {title = "Duna", author = "Frank Herbert", loanStatus = Borrowed "Peter"}

borrowBook "Peter" book2 == book2  -- True, už bola požičaná Jane

returnBook – vrátenie knihy

returnBook :: Book -> Book
returnBook book = book { loanStatus = Available }

Netreba nič kontrolovať. Či bola kniha požičaná alebo nie, po vrátení je Available.


3. Úloha 3.2 – borrowBook s Maybe

Maybe Book znamená „možno kniha“. Má dve možné hodnoty:

hodnota znamená
Just kniha operácia sa podarila, tu je výsledok
Nothing operácia sa nepodarila

Je to ako Optional v Jave. Funkcia tak jasne povie, že vypožičanie zlyhalo, namiesto toho, aby potichu vrátila pôvodnú knihu.

borrowBook :: String -> Book -> Maybe Book
borrowBook person book
  | loanStatus book == Available = Just (book { loanStatus = Borrowed person })
  | otherwise                    = Nothing

Oproti 3.1 sa zmenili len dve veci:

  1. typ výsledku: Book → Maybe Book
  2. úspešný výsledok je zabalený v Just (...), neúspešný je Nothing

Zátvorky za Just nie sú nutné, úprava poľa (book { ... }) sa vyhodnotí ako prvá. Sú tam len kvôli čitateľnosti, aby bolo hneď vidno, čo je zabalené v Just.

borrowBook "Peter" book1  -- Just (Book {..., loanStatus = Borrowed "Peter"})
borrowBook "Peter" book2  -- Nothing

V help.hs sa táto verzia volá borrowBookMaybe, aby mohli byť obe verzie v jednom súbore (dve funkcie s rovnakým menom v jednom súbore byť nemôžu). V úlohe sa však mení priamo borrowBook, takže pri odovzdaní pôvodnú verziu nahraď touto a nechaj meno borrowBook.


4. Časté chyby

  • Kód mimo funkcie. Riadok ako name (Person "John" 30) == "John" je zo zadania len príklad na GHCi. V .hs súbore na najvyššej úrovni byť nemôže, lebo nie je to definícia. Buď ho zmaž, alebo ho daj do komentára (-- ...).
  • title books namiesto map title books. title berie jednu knihu, nie zoznam.
  • Borrowed bez mena. loanStatus b == Borrowed nefunguje, Borrowed potrebuje meno: Borrowed person. Ak chceš zistiť len „je požičaná komukoľvek?“, použi /= Available.
  • Chýba deriving Eq. Bez neho nefunguje == na LoanStatus ani Book.

Top